'==========================================================================
Sub ModuleSichern ()
' Aufgabe:   Speichern aller Module in Dateien
' Autor:     Chris Juengling Juengling@gus.de
' fuer Access 2.0   OHNE GEWÄHR !!!
'==========================================================================

Const A_SAVETEXTAS = 4          ' Ist leider nicht vordefiniert!

Dim AktuelleDB As Database
Dim ModulContainer As Container, Dokument As Document
Dim i As Integer
Dim Dateiname As String

'------------------------------

Set AktuelleDB = DBEngine(0)(0)
Set ModulContainer = AktuelleDB.Containers("Modules")
	
Debug.Print
Debug.Print "Letzte Änderung", "Dateiname", "Modul"
Debug.Print "-------------------------------------------------------------"

For i = 0 To ModulContainer.documents.count - 1
    Set Dokument = ModulContainer.documents(i)
    Debug.Print Dokument.LastUpdated, ;
	    
    Dateiname = CStr(Dokument.Name) + ".txt"
    Debug.Print Dateiname, ;
    On Error Resume Next: Kill Dateiname: On Error GoTo 0
    DoCmd OpenModule Dokument.Name
    SendKeys Dateiname & "{ENTER}"
    DoCmd DoMenuItem A_MODULE, A_FILE, A_SAVETEXTAS
    Debug.Print Dokument.Name
    DoCmd Close
Next i

End Sub